History buttons

Protected · September 5, 2010 at 4:57 AM

Hey again. I need history buttons for my website, and I tried adding these: Button to select the last panorama that was viewed

Unfortunately, the buttons do not work. When I try to click the back button, I get this error:

http://www.example.com/http://www.example.com/?file=name - loading error (IO error)

Now, it's obvious why the messed up URL isn't working. But since the history buttons are pulling the panorama's location straight from xml.url, does this mean the contents of xml.url are wrong? Or is the path section of the URL being duplicated elsewhere?

When actually loading the panoramas (from my hotspots), I only include the "?file=name" part, no path at all, since my xml is generated on the fly by index.php. So the path shouldn't even be there once, much less twice!

Protected · September 5, 2010 at 5:14 AM

Hm, something else seems to be wrong; The back button always goes back to the very first panorama? Is it just here?

pinsane · September 5, 2010 at 8:26 AM

Hi,

Can you post a link (and the post the location of your xml)? This would help us to debug this. Are you using scenes, because the history code does not work with scene-based tours.

steve

Protected · September 5, 2010 at 7:30 PM

Hi! Thanks for your interest.

(EDIT: I am not using scenes.)

I can't show you all of my xml or link to it because it's generated on the fly using php. The history buttons I was using were pretty much copied straight from your number 1 xml file - the delete, new, back and forward actions and the button plugins, as well as the call to new onxmlcomplete of course. I tried messing around with your code and even rewrite it, but I soon got pissed at how limited and weird the if command is (it kept getting ignored when the condition contained certain constructs, for no apparent reason) so I decided to write my history manager as a plugin. Here it is:

Code

import krpano_as3_interface;


var krpano:krpano_as3_interface;
var plugin:Object;
var history:Array = new Array();
var position:Number = -1;
stop();
if (stage == null) {
	addEventListener(Event.ADDED_TO_STAGE, startplugin);
	addEventListener(Event.REMOVED_FROM_STAGE, stopplugin);
}
function startplugin(event:Event):void {
	krpano = krpano_as3_interface.getInstance();
	krpano.addPluginEventListener(this, krpano_as3_interface.PLUGINEVENT_REGISTER, registerEvent);
}
function stopplugin(event:Event):void {
	krpano.removePluginEventListener(this, krpano_as3_interface.PLUGINEVENT_REGISTER, registerEvent);
	krpano = null;
}
function registerEvent(evt:DataEvent):void {
	var path:String = evt.data;
	plugin = krpano.get(path);
	plugin.register = update;
	plugin.back = prev;
	plugin.forward = fw;
	if (!plugin.hasOwnProperty("backbutton")) plugin.backbutton = null;
	if (!plugin.hasOwnProperty("fwbutton")) plugin.fwbutton = null;
}
function update(place:String):void {
	if (history.length < 1 || history[position] != place) {
		if (history.length > 0)
			history = history.slice(0, position+1);
		history.push(place);
		position = history.length - 1;
		if (plugin.fwbutton != null)
			krpano.set("plugin[" + plugin.fwbutton + "].visible", false);
		if (plugin.backbutton != null && position > 0)
			krpano.set("plugin[" + plugin.backbutton + "].visible", true);
	}
}
function prev():void {
	if (position > 0) {
		position -= 1;
		krpano.call("loadpano(" + history[position] + ",null,MERGE,BLEND(2));");
		if (plugin.backbutton != null && position == 0)
			krpano.set("plugin[" + plugin.backbutton + "].visible", false);
		if (plugin.fwbutton != null)
			krpano.set("plugin[" + plugin.fwbutton + "].visible", true);
	}
}
function fw():void {
	if (position < history.length - 1) {
		position += 1;
		krpano.call("loadpano(" + history[position] + ",null,MERGE,BLEND(2));");
		if (plugin.fwbutton != null && position == history.length - 1)
			krpano.set("plugin[" + plugin.fwbutton + "].visible", false);
		if (plugin.backbutton != null)
			krpano.set("plugin[" + plugin.backbutton + "].visible", true);
	}
}

Display More

How to use:

Code

<plugin name="history" url="history.swf" backbutton="back_button" fwbutton="forward_button" keep="true" preload="true" />
<events onxmlcomplete="plugin[history].register(get(my.filename));" />


<plugin name="back_button"
    	url="prev.png"
    	keep="true"
    	visible="false"
    	onclick="plugin[history].back();" />
<plugin name="forward_button"
    	url="next.png"
    	keep="true"
    	visible="false"
    	onclick="plugin[history].forward();" />

Display More

You must customize the buttons to taste and you can also change the plugin itself to add tweens and other stuff. Passing the button names to the plugin is optional and only needed if you want it to control the visibility of said buttons. my.filename contains the XML filename; Since xml.url is borked on my site I created my own filename field which is filled on the fly by php, but you can replace my.filename with xml.url if xml.url works for you.

pinsane · September 5, 2010 at 8:23 PM

Glad to hear things worked out. If you ever figure out why the xml.url is getting such a peculiar value I'd be interested.

Steve

History buttons

Participate now!

Users Viewing This Thread